From 4f2bda6a9c188f0c7d028b02b93ab3978fb7543c Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Gustav=20S=C3=B6rn=C3=A4s?= <gustav@sornas.net>
Date: Fri, 11 Sep 2020 09:21:45 +0200
Subject: TDDD86 labb 1 redovisning

---
 labb1/Life.pro | 47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 labb1/Life.pro

diff --git a/labb1/Life.pro b/labb1/Life.pro
new file mode 100644
index 0000000..f6df0e9
--- /dev/null
+++ b/labb1/Life.pro
@@ -0,0 +1,47 @@
+TEMPLATE = app
+
+CONFIG += console
+# Make sure we do not accidentally #include files placed in 'resources'
+CONFIG += no_include_pwd
+
+SOURCES = $$PWD/src/*.cpp
+SOURCES += $$PWD/lib/*.cpp
+HEADERS = $$PWD/src/*.h
+HEADERS += $$PWD/lib/StanfordCPPLib/*.h
+HEADERS += $$PWD/lib/*.h
+
+QMAKE_CXXFLAGS += -std=c++11
+
+INCLUDEPATH += $$PWD/lib/StanfordCPPLib/
+INCLUDEPATH += $$PWD/lib/
+
+# Copies the given files to the destination directory
+defineTest(copyToDestdir) {
+    files = $$1
+
+    for(FILE, files) {
+        DDIR = $$OUT_PWD
+
+        # Replace slashes in paths with backslashes for Windows
+        win32:FILE ~= s,/,\\,g
+        win32:DDIR ~= s,/,\\,g
+
+        !win32 {
+            QMAKE_POST_LINK += cp -r '"'$$FILE'"' '"'$$DDIR'"' $$escape_expand(\\n\\t)
+        }
+        win32 {
+            QMAKE_POST_LINK += xcopy '"'$$FILE'"' '"'$$DDIR'"' /e /y $$escape_expand(\\n\\t)
+        }
+    }
+
+    export(QMAKE_POST_LINK)
+}
+!win32 {
+    copyToDestdir($$files($$PWD/res/*))
+}
+win32 {
+    copyToDestdir($$PWD/res)
+}
+macx {
+    cache()
+}
-- 
cgit v1.2.1