From 0c39051ba80f04b1177833a006f2d442a7170b56 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Gustav=20S=C3=B6rn=C3=A4s?= <gustav@sornas.net>
Date: Thu, 3 Dec 2020 17:11:43 +0100
Subject: add initial files l8

---
 labb8/Trailblazer.pro | 68 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100755 labb8/Trailblazer.pro

(limited to 'labb8/Trailblazer.pro')

diff --git a/labb8/Trailblazer.pro b/labb8/Trailblazer.pro
new file mode 100755
index 0000000..75d3122
--- /dev/null
+++ b/labb8/Trailblazer.pro
@@ -0,0 +1,68 @@
+TEMPLATE = app
+
+# Make sure we do not accidentally #include files placed in 'resources'
+CONFIG += no_include_pwd
+
+# Reduce compile times and avoid configuration confusion by excluding Qt libs
+#CONFIG -= qt
+
+# Do not create an app bundle when running on OS X
+#CONFIG -= app_bundle
+
+SOURCES = $$PWD/src/*.cpp
+SOURCES += $$PWD/lib/StanfordCPPLib/*.cpp
+
+HEADERS = $$PWD/src/*.h
+HEADERS += $$PWD/lib/StanfordCPPLib/*.h
+# HEADERS += $$PWD/lib/StanfordCPPLib/private/*.h
+
+# GCC defaults to not warning about failing to return from a non-void function
+# We enable this warning manually, since Clang warns by default
+QMAKE_CXXFLAGS += -std=c++11 -Wreturn-type
+
+# These flags increase the recursion stack size so that recursive DFS doesn't
+# exhaust all available stack space on large graphs
+QMAKE_CXXFLAGS += -fno-stack-limit -fstack-check
+
+INCLUDEPATH += $$PWD/lib/StanfordCPPLib/
+
+# Copies the given files to the destination directory
+# The rest of this file defines how to copy the resources folder
+defineTest(copyToDestdir) {
+    files = $$1
+
+    for(FILE, files) {
+        DDIR = $$OUT_PWD
+
+        # Replace slashes in paths with backslashes for Windows
+        win32:FILE ~= s,/,\\,g
+        win32:DDIR ~= s,/,\\,g
+
+        !win32 {
+            copyResources.commands += cp -r '"'$$FILE'"' '"'$$DDIR'"' $$escape_expand(\\n\\t)
+        }
+        win32 {
+            copyResources.commands += xcopy '"'$$FILE'"' '"'$$DDIR'"' /e /y $$escape_expand(\\n\\t)
+        }
+    }
+    export(copyResources.commands)
+}
+
+!win32 {
+    copyToDestdir($$files($$PWD/res/*))
+    copyToDestdir($$files($$PWD/lib/*.jar))
+}
+win32 {
+    QMAKE_LFLAGS += -Wl,--stack,100000000   # stop stack from overflowing
+    copyToDestdir($$PWD/res)
+    copyToDestdir($$PWD/lib/*.jar)
+}
+
+copyResources.input = $$files($$PWD/res/*)
+OTHER_FILES = $$files(res/*)
+QMAKE_EXTRA_TARGETS += copyResources
+POST_TARGETDEPS += copyResources
+
+macx {
+    cache()
+}
-- 
cgit v1.2.1